Retour

Source : yzr.mp

yzr.mp
input fonctions;
 
u = 10cm;
 
verbatimtex
%&latex
\documentclass{minimal}
\usepackage[garamond]{mathdesign}
\begin{document}
etex
 
 
 
vardef Y(expr t) =
    u * (sin(t) ** 2)
enddef;
 
vardef Z(expr t) =
    u * ((cos(t + .5 * (sin(t)**2)))**2)
enddef;
 
vardef R(expr t) =
    u / 2 * (1 + .8 * sin(2*t + (sin(t)**2)))
enddef;
 
yzr.mp (figure 1)
beginfig(1);
    drawarrow (0,0) -- (0,1.2u) withpen pencircle scaled 1.5pt;
    drawarrow (0,0) -- (1.2u,0) withpen pencircle scaled 1.5pt;
    draw (.5u,.01u) -- (.5u,-.01u);
    draw (u,.01u) -- (u,-.01u);
    draw (-.01u,.5u) -- (.01u,.5u);
    draw (-.01u,u) -- (.01u,u) ;
    label.llft(btex $O$ etex scaled 2,(0,0));
    label.lft(btex $0.5$ etex scaled 2, (-.01u,.5u));
    label.lft(btex $1$ etex scaled 2, (-.01u,u));
    label.bot(btex $0.5$ etex scaled 2, (0.5u,-.01u));
    label.bot(btex $1$ etex scaled 2, (u,-.01u));
    label.bot(btex $y$ etex scaled 2, (1.2u,-.01u));
    label.lft(btex $z$ etex scaled 2, (-.01u,1.2u));
    dt = Pi/100;
    draw (Y(0),Z(0)) ... for i:=1 upto 100: (Y(i*dt),Z(i*dt)) ... endfor cycle
	withpen pencircle scaled 2.5pt
	withcolor (.9,.7,.6);    
    drawarrow (0,u) -- (.2u,.8u) withcolor (.1,.3,.4);	
    label(btex \(y =\sin^2 t\quad z= \cos^2(t +\frac12\sin^2t)\) etex scaled 2.5,(.6u,-.2u));
endfig;
 
yzr.mp (figure 2)
beginfig(2);
    drawarrow (0,0) -- (0,u) withpen pencircle scaled 1.5pt;
    drawarrow (0,0) -- (1.7u,0) withpen pencircle scaled 1.5pt;
    draw ((Pi/4)*u,.01u) -- ((Pi/4)*u,-.01u);
    draw ((Pi/2)*u,.01u) -- ((Pi/2)*u,-.01u);
    draw (-.01u,.5u) -- (.01u,.5u);
    label.llft(btex $O$ etex scaled 2,(0,0));
    label.lft(btex $1$ etex scaled 2, (-.01u,.5u));
    label.bot(btex $\pi/2$ etex scaled 2, ((Pi/4)*u,-.01u));
    label.bot(btex $\pi$ etex scaled 2, ((Pi/2)*u,-.01u));
    label.bot(btex $t$ etex scaled 2, (1.7u,-.01u));
    label.lft(btex $R$ etex scaled 2, (-.01u,u));
    draw (0,R(0)) for i:=1 upto 100: ... (i*dt*u/2,R(i*dt)) endfor
	withpen pencircle scaled 2.5pt
	withcolor (.7,.8,.9);    
    label(btex \(R = 1 + \frac45\sin(2t+\sin^2t)\) etex scaled 2.5,(.85u,-.2u));
endfig;
 
end