%@Auteur: Maxime Chupin
 
 verbatimtex 
 %&latex 
 \documentclass{article} 
 \usepackage[latin1]{inputenc}
 \usepackage{amsmath}
 \usepackage{fourier}
 \begin{document} 
 \large
 etex 
 
 labeloffset := 8;
 
 u=3cm;
 v=3mm;
 
 
 vardef proj(expr P,M,N) =
      save H; pair H;
      H = whatever [M,N]; H - P = whatever * (M - N) rotated 90; H
 enddef;
 
 
 vardef droite(expr a,b) =
     10[a,b]--10[b,a]
 enddef;
 
 path carre;
 carre = (0,0)--(1,0)--(1,1)--(0,1)--cycle;
 
 path parabole;
 parabole = (3.466u,-2.30940u)..(3.1333u,-2.06559u)..(2.8u,-1.78885u)
             ..(2.1333u,-1.03279u)..{dir 90}(1.8u,0){dir 90}
             ..(2.1333u,1.03279u)..(2.4666u,1.46059u)..(2.8u,1.78885u)
             ..(3.1333u,2.06559u)..(3.466u,2.30940u);
 
 pair O,I,M,M',K,K',F,H,H';
 
 F  := (2.6u,0);
 K  := (u,0);
 K' := (u,3u);
 
 for i=1 upto 60:
  beginfig(i);
 
     pickup pencircle scaled 1pt;
 
     % axe focal
     draw (0,0)--(5u,0);
     % directrice
     draw (u,-2u)--(u,2u);
 
     x := 2.6 + 0.4 * cosd(6i);
     M := ((x*u,0)--(x*u,3u)) intersectionpoint parabole;
 
     draw parabole withcolor red;
 
     % vecteurs i et j
     drawarrow (1.8u,0)--(2.4u,0);
     drawarrow (1.8u,0)--(1.8u,0.6u);
     pickup pencircle scaled 0.5pt;
 
     H := proj(M,K,K');
     dotlabel.lrt(btex $H$ etex, H);
 
     % droite pointille
     draw H--M dashed evenly;
     draw F--H dashed evenly;
 
     % milieu de HF
     I := 0.5[H,F];
 
     % M'
     draw droite(F,M);
     M' := droite(F,M) intersectionpoint parabole;
     dotlabel.urt(btex $M'$ etex, M');
     
     % projeté de M' sur la tangente issue de M
     O := proj(M',M,I);
     dotlabel.lft(btex $O$ etex,O);
 
     % carre
     draw carre scaled 10 rotated (angle(O-M)+90) shifted O
 	dashed evenly withcolor 0.2white;
 
     % tangente en M
     pickup pencircle scaled 0.7pt;
     draw droite(I,M) withcolor blue;
     pickup pencircle scaled 0.5pt;
 
     % deuxieme tangente
     pickup pencircle scaled 0.7pt;
     draw droite(O,M') withcolor blue;
     pickup pencircle scaled 0.5pt;
 
     % projete de M' sur la directrice
     H':=proj(M',K,K');
     dotlabel.lrt(btex $H'$ etex, H');
     draw H'--M' dashed evenly;
 
 
     % K
     dotlabel.ulft(btex $K$ etex,(u,0));
     % F
     dotlabel.lrt(btex $F$ etex,F);
     dotlabel.lrt(btex $M$ etex,M);
 
     % S
     dotlabel.llft(btex $S$ etex,(1.8u,0));
     % D
     label.ulft(btex $\cal D$ etex,(u,-2u));
 
     % delta
     label.top(btex $\Delta$ etex,(4.8u,0));
 
     % i,j
     label.bot(btex $\vec i$ etex, (2.1u,0));
     label.lft(btex $\vec j$ etex, (1.8u,0.3u));
     
     clip currentpicture to 
 	(0,-2u)--(0,2u)--(5u,2u)--(5u,-2u)--cycle;
 
   endfig;
 endfor;
 end