Retour

Source : saisons3C.mp

saisons3C.mp
verbatimtex
%&latex
\documentclass{article}
\usepackage{fourier}
\begin{document}
etex
 
saisons3C.mp (figure 1)
beginfig(1);
 
    % excentricité, demi-grand axe, demi-petit axe
    numeric e,a,b;
    e = 0.2;
    a = 100;
    b = a * sqrt(1 - e * e) ;
 
    % ellipse
    path el;
    el = (fullcircle xscaled 2a yscaled 2b) rotated -78;
 
    pair S,T;
    % soleil vrai
    S = point 5.2 of el;
    % terre
    T = (sqrt(a**2-b**2),0) rotated -78;
 
    % axes
    draw ((-1.1a,0) -- (1.1a,0)) shifted T;
    draw ((0,-a) -- (0,1.3a)) shifted T;
 
    draw el;
    % ligne des apsides
    draw ((-a,0)--(a,0)) rotated -78;
 
    % marque des angles
    path t[];
    t1 = reverse (((fullcircle scaled 30 rotated -78) shifted T) 
	cutafter (T--(T shifted (20,0))));
    t2 = ((fullcircle scaled 20 rotated -78) shifted T) cutafter (T--S);
    drawarrow t2;
    drawarrow t1;
    draw T--S;
 
    % le soleil
    label(btex $S$ etex, 1.1S);
    draw S withpen pencircle scaled 6pt withcolor (1,1,0);
 
    label.urt(btex $v$ etex,point 3 of t2);
    label.lrt(btex $\varpi$ etex,point 1 of t1);
    label.urt(btex $\gamma$ $0^{\tiny\circ}$ etex,(.92a,0)shifted T);
    label.urt(btex $90^{\tiny\circ}$ etex,(0,(1+e)*a)shifted T);
    label.ulft(btex $180^{\tiny\circ}$ etex,(-a,0)shifted T);
    label.llft(btex $270^{\tiny\circ}$ etex,(0,(-1+e)*a)shifted T);
    dotlabel.llft(btex $T$ etex, T);
    dotlabel.urt(btex $A$ etex, (-a,0) rotated -78);
    dotlabel.llft(btex $P$ etex, (a,0) rotated -78);
endfig;
 
end