Fichier losange-oa2009.mp (figure 1) — Modifié le 4 Octobre 2009 à 23 h 23
verbatimtex
%&latex
\documentclass{minimal}
\usepackage{fourier}
\begin{document}
etex
u = 0.5cm;
pair A,B,C,D,E,E',B',J,F;
A := origin;
B := u*(0,16);
C := u*(8,16);
D := u*(8,0);
B':= B reflectedabout (A,C);
E := (C--D) intersectionpoint (A--B');
E':= E reflectedabout (A,C);
J := (B--B') intersectionpoint (C--D);
F := (B--B') intersectionpoint (A--C);
labeloffset := 4.5;
beginfig(1);
draw A--B--C--D--cycle;
fill (B--C--E'--cycle)
withcolor (1,0.9,0.95);
draw (B--C--E'--cycle)
withpen pencircle scaled 1
withcolor (0.5,0.2,0.25);
fill (A--B'--C--D--cycle)
withcolor (1,0.9,0.95);
draw (A--B'--C--D--cycle)
withpen pencircle scaled 1
withcolor (0.5,0.2,0.25);
draw A--C;
draw B--B' withpen pencircle scaled 1;
dotlabel.llft(btex \(A\) etex, A);
dotlabel.ulft(btex \(B\) etex, B);
dotlabel.urt(btex \(C\) etex, C);
dotlabel.lrt(btex \(D\) etex, D);
dotlabel.rt(btex \(B'\) etex,B');
dotlabel.lrt(btex \(E\) etex,E);
dotlabel.lft(btex \(E'\) etex,E');
dotlabel.urt(btex \(J\) etex,J);
dotlabel.bot(btex \(F\) etex,F);
endfig;
end